#include "colors.inc"

camera {
  location <0, 2.5, -6>
  look_at <0, 0, 0>
}

/*sky_sphere {
  pigment {
    gradient y
    color_map { [0.0 color blue 0.6] [1.0 color rgb 1] }
  }
}*/

light_source { <-3, 30, -30> White }

// ----------------------------------------

#declare BlurAmt = .05;

#macro MotionBlurredMap(mblur, acol, bcol)
  #local blur = mblur / 2;
  #if (blur < .25)
    color_map {
      [0.0        color bcol]
      [0.0 + blur color acol]
      [0.5 - blur color acol]
      [0.5 + blur color bcol]
      [1.0 - blur color bcol]
    }
  #else
    #local mix_this_fac = (blur - .25) * 2;
    #local mix_other_fac = 1 - mix_this_fac;
    #local facol = acol * mix_this_fac + bcol * mix_other_fac;
    #local fbcol = bcol * mix_this_fac + acol * mix_other_fac;
    color_map {
      [0.0 color fbcol]
      [0.5 color facol]
      [1.0 color fbcol]
    }
  #end
#end

cylinder {
  0, -1*y, 1
  texture {
    pigment {
      radial frequency 3
      MotionBlurredMap(.5, color Red, color White)
    }
    finish{specular 1}
  } 
  rotate -90*x
  rotate clock*360*z
  translate -1.5*x
}

cylinder {
  0, -1*y, 1
  texture {
    pigment {
      radial frequency 3
      MotionBlurredMap(0, color Red, color White)
    }
    finish{specular 1}
  } 
  rotate -90*x
  rotate clock*360*z
  translate 1.5*x
}